Veliki angleško-slovenski slovar

Veliki angleško-slovenski slovar, 3.2 version on Wikibase

• The item describing this dictionary is Q34680.
• The source file is named ENSL-V_DMlex_3.2.xml
• Comments are listed here: https://github.com/dlindem/dmlex-wikibase/blob/main/comments/ENSL-V-3.2-comments.md

Entries

English-Slovene dictionary

Display senses and sense translations using this query.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>
PREFIX lpr: <https://lexbib.elex.is/prop/reference/>
PREFIX lno: <https://lexbib.elex.is/prop/novalue/>

select distinct ?entry ?lemma (lang(?lemma) as ?lang) ?posLabel
  (group_concat(distinct concat(?label," (",?labeltype,")"); SEPARATOR=" | ") as ?otherLabels)
  (count(distinct ?expl) as ?examples)
  ?sense ?sense_num
  (group_concat(distinct str(?def); SEPARATOR =", ") as ?definitions)
  (group_concat(distinct str(?trans); SEPARATOR=" | ") as ?translations)
  

where { 
  ?entry ldp:P5 lwb:Q111; ldp:P207 lwb:Q34680; wikibase:lemma ?lemma; wikibase:lexicalCategory ?pos.
  optional {?entry ldp:P203 ?dmlex_label. ?dmlex_label rdfs:label ?label. filter(lang(?label)="en")
            ?dmlex_label ldp:P191 [rdfs:label ?labeltype]. filter(lang(?labeltype)="en")}
  optional {?entry ontolex:sense ?sense. bind (replace(str(?sense), "https://lexbib.elex.is/entity/L[0-9]+-S", "") as ?sense_num)
      optional {?sense ldp:P218 ?def.}
      optional {?sense skos:definition ?trans.}
           }
  optional {{?entry ldp:P204 ?pron.} union {?entry ontolex:sense [ldp:P204 ?pron].}}
  optional {{?entry ldp:P213 ?expl.} union {?entry ontolex:sense [ldp:P213 ?expl].}}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } group by ?entry ?lemma ?posLabel ?otherLabels ?examples ?sense ?sense_num
    ?definitions ?translations 
order by lcase(?lemma) xsd:integer(?sense_num)

Try it!

Slovene translation equivalents

This query lists distinct Slovene headword translations, and the English headwords and English lexical entry senses they correspond to, ranked according to the number of English lem-pos entities translated by the same Slovene lem-pos entity.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>
PREFIX lpr: <https://lexbib.elex.is/prop/reference/>
PREFIX lno: <https://lexbib.elex.is/prop/novalue/>

select distinct 
?target_lemma 
?posLabel 
(count(?origin_lemma) as ?origins) 
(group_concat(str(?origin_sense); SEPARATOR=", ") as ?origin_senses)

where { 
  ?entry ldp:P5 lwb:Q111; ldp:P207 lwb:Q34680; wikibase:lemma ?origin_lemma.
  ?entry ontolex:sense ?sense. 
  bind(concat(str(?origin_lemma)," (",strafter(str(?sense),str(lwb:)), ")") as ?origin_sense)
  ?sense skos:definition ?trans; ldp:P224 ?target_sense. 
  ?target_entry ontolex:sense ?target_sense; wikibase:lemma ?target_lemma; wikibase:lexicalCategory ?pos.
  
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } 
group by ?target_lemma ?posLabel ?origins ?origin_senses
order by desc(?origins) ?target_lemma

Try it!

Relations

This query lists all relations in this dictionary.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>

select distinct ?origin ?originId ?originLemma ?relationType ?target ?targetId ?targetLemma
where {?origin lp:P5 [lps:P5 lwb:Q111; lpq:P186 ?originId]; ldp:P207 lwb:Q34680; lp:P214 [lps:P214 ?target; lpq:P223 [rdfs:label ?relationType]]; wikibase:lemma ?originLemma. 
       ?target lp:P5 [lps:P5 lwb:Q111; lpq:P186 ?targetId]; wikibase:lemma ?targetLemma. 
      }
order by lcase(?originLemma)

Try it!