Slovensko-srbohrvaški slovar

Slovensko-angleški slovar, 3.3 version on Wikibase

• The item describing this dictionary is Q34935.
• The source dataset is named SLSH_DMlex_3.3.xml
• Comments are here: https://github.com/dlindem/dmlex-wikibase/blob/main/comments/SLSH-3.2-comments.md

Entries

Slovene-Serbocroatian dictionary

Display senses and sense translations using this query.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>
PREFIX lpr: <https://lexbib.elex.is/prop/reference/>
PREFIX lno: <https://lexbib.elex.is/prop/novalue/>

select distinct ?entry ?lemma (lang(?lemma) as ?lang) ?posLabel
  (group_concat(distinct concat(?label," (",?labeltype,")"); SEPARATOR=" | ") as ?otherLabels)
  (count(distinct ?expl) as ?examples)
  ?sense ?sense_num
  (group_concat(distinct str(?def); SEPARATOR =", ") as ?definitions)
  (group_concat(distinct str(?trans); SEPARATOR=" | ") as ?translations)
  

where { 
  ?entry ldp:P5 lwb:Q111; ldp:P207 lwb:Q34935; wikibase:lemma ?lemma; wikibase:lexicalCategory ?pos.
  optional {?entry ldp:P203 ?dmlex_label. ?dmlex_label rdfs:label ?label. filter(lang(?label)="en")
            ?dmlex_label ldp:P191 [rdfs:label ?labeltype]. filter(lang(?labeltype)="en")}
  optional {?entry ontolex:sense ?sense. bind (replace(str(?sense), "https://lexbib.elex.is/entity/L[0-9]+-S", "") as ?sense_num)
      optional {?sense ldp:P218 ?def.}
      optional {?sense skos:definition ?trans.}
           }
  optional {{?entry ldp:P204 ?pron.} union {?entry ontolex:sense [ldp:P204 ?pron].}}
  optional {{?entry ldp:P213 ?expl.} union {?entry ontolex:sense [ldp:P213 ?expl].}}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } group by ?entry ?lemma ?posLabel ?otherLabels ?examples ?sense ?sense_num
    ?definitions ?translations 
order by lcase(?lemma) xsd:integer(?sense_num)

Try it!

Serbocroatian translation equivalents

This query lists distinct Serbocroatian headword translations, and the Slovene headwords and Slovene lexical entry senses they correspond to, ranked according to the number of Slovene lem-pos entities translated by the same Serbocroatian lem-pos entity.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>
PREFIX lpr: <https://lexbib.elex.is/prop/reference/>
PREFIX lno: <https://lexbib.elex.is/prop/novalue/>

select distinct 

(group_concat(str(?origin_sense); SEPARATOR=", ") as ?sl_senses)
?posLabel 
(count(?origin_sense) as ?sh_entry_count)
(group_concat(str(?target_lexeme); SEPARATOR=", ") as ?sh_entries)
?sh_translation_lemma 

where { 
  ?entry ldp:P5 lwb:Q111; ldp:P207 lwb:Q34935; wikibase:lemma ?origin_lemma.
  ?entry ontolex:sense ?sense. 
  bind(concat(str(?origin_lemma)," (",strafter(str(?sense),str(lwb:)), ")") as ?origin_sense)
  ?sense skos:definition ?trans; ldp:P224 ?target_sense. 
  ?target_entry ontolex:sense ?target_sense; wikibase:lemma ?sh_translation_lemma; wikibase:lexicalCategory ?pos.
  bind(strafter(str(?target_entry),str(lwb:)) as ?target_lexeme)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } 
group by ?sl_senses ?posLabel ?sh_entry_count ?sh_entries ?sh_translation_lemma 
order by desc(?sh_entry_count) ?sh_translation_lemma

Try it!

Serbocroatian translation equivalents

This query lists distinct Serbocroatian headword translations, and the Slovene headwords and Slovene lexical entry senses they correspond to, and shows groups of Slovene senses that are translated the same. The Serbocroatian lexemes of the groups are to be merged, so that their single senses become senses of the merged item.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>
PREFIX lpr: <https://lexbib.elex.is/prop/reference/>
PREFIX lno: <https://lexbib.elex.is/prop/novalue/>

select distinct 
?sl_lemma
(group_concat(str(?origin_sense); SEPARATOR=", ") as ?sl_senses)
?posLabel 
(count(?origin_sense) as ?sh_entry_count)
(group_concat(str(?target_lexeme); SEPARATOR=", ") as ?sh_merge_candidates)
?sh_translation_lemma 

where { 
  ?entry ldp:P5 lwb:Q111; ldp:P207 lwb:Q34935; wikibase:lemma ?sl_lemma.
  ?entry ontolex:sense ?sense. 
  bind(concat(str(?sl_lemma)," (",strafter(str(?sense),str(lwb:)), ")") as ?origin_sense)
  ?sense skos:definition ?trans; ldp:P224 ?target_sense. 
  ?target_entry ontolex:sense ?target_sense; wikibase:lemma ?sh_translation_lemma; wikibase:lexicalCategory ?pos.
  bind(strafter(str(?target_entry),str(lwb:)) as ?target_lexeme)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  } 
group by ?sl_lemma ?sl_senses ?posLabel ?sh_entry_count ?sh_merge_candidates ?sh_translation_lemma 
order by desc(?sh_entry_count) ?sh_translation_lemma

Try it!

Relations

This query lists all relations in this dictionary.

PREFIX lwb: <https://lexbib.elex.is/entity/>
PREFIX ldp: <https://lexbib.elex.is/prop/direct/>
PREFIX lp: <https://lexbib.elex.is/prop/>
PREFIX lps: <https://lexbib.elex.is/prop/statement/>
PREFIX lpq: <https://lexbib.elex.is/prop/qualifier/>

select distinct ?origin ?originId ?originLemma ?relationType ?target ?targetId ?targetLemma
where {?origin lp:P5 [lps:P5 lwb:Q111; lpq:P186 ?originId]; ldp:P207 lwb:Q34935; lp:P214 [lps:P214 ?target; lpq:P223 [rdfs:label ?relationType]]; wikibase:lemma ?originLemma. 
       ?target lp:P5 [lps:P5 lwb:Q111; lpq:P186 ?targetId]; wikibase:lemma ?targetLemma. 
      }
order by lcase(?originLemma)

Try it!